ウィルコクソン検定

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > ウィルコクソン検定

Keyword: ウィルコクソン, Wilcoxon Test, 検定

概要

本サンプルはウィルコクソン符号順位検定（Wilcoxon Signed Rank Test) を行うFortranによるサンプルプログラムです。本サンプルは以下に示される１対の標本を分析対象とし、検定統計量と自由度、両側確率を出力します。

ウィルコクソン検定のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g08agf() のExampleコードです。本サンプル及びルーチンの詳細情報は g08agf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はg08agf のマニュアルページを参照）

このデータをダウンロード

G08AGF Example Program Data
 8  0.0  'T' 'N'                         :: N,XME,TAIL,ZER
82.0 69.0 73.0 43.0 58.0 56.0 76.0 65.0  :: X
63.0 42.0 74.0 37.0 51.0 43.0 80.0 62.0  :: Y

１行目はタイトル行で読み飛ばされます。
２行目に標本のサイズ(n)、メディアン検定値(xme)、裾確率の種類(tail)、d_i=0.0の場合を順位付けに含めるかどうかを示すフラグ(zer)を指定しています。
３～４行目に標本のデータ(x,y)を指定しています。

出力結果

（本ルーチンの詳細はg08agf のマニュアルページを参照）

この出力例をダウンロード

 G08AGF Example Program Results

 Wilcoxon one sample signed ranks test

 Data values
     82.0 69.0 73.0 43.0 58.0 56.0 76.0 65.0
     63.0 42.0 74.0 37.0 51.0 43.0 80.0 62.0

 Test statistic            =  32.0000
 Normalized test statistic =   1.8904
 Degrees of freedom        =        8
 Two tail probability      =   0.0547

６～７行目には読み込まれた１対の標本のデータが出力されています。
９行目には検定統計量が出力されています。
１０行目には正規検定統計量が出力されています。
１１行目には自由度が出力されています。
１２行目には両側確率（two tail probability）が出力されています。

ソースコード

（本ルーチンの詳細はg08agf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g08agfe

!      G08AGF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g08agf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: p, w, wnor, xme
       INTEGER                         :: ifail, n, n1
       CHARACTER (1)                   :: tail, zer
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: wrk(:), x(:), y(:), z(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'G08AGF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the problem size, median test value and details of
!      test to perform
       READ (nin,*) n, xme, tail, zer

       ALLOCATE (x(n),y(n),z(n),wrk(3*n))

!      Read in data
       READ (nin,*) x(1:n)
       READ (nin,*) y(1:n)

!      Display title
       WRITE (nout,*) 'Wilcoxon one sample signed ranks test'
       WRITE (nout,*)

!      Display input data
       WRITE (nout,*) 'Data values'
       WRITE (nout,99999) x(1:n)
       WRITE (nout,99999) y(1:n)

!      Calculate difference
       z(1:n) = x(1:n) - y(1:n)

!      Perform test
       ifail = 0
       CALL g08agf(n,z,xme,tail,zer,w,wnor,p,n1,wrk,ifail)

!      Display results
       WRITE (nout,*)
       WRITE (nout,99998) 'Test statistic            = ', w
       WRITE (nout,99998) 'Normalized test statistic = ', wnor
       WRITE (nout,99997) 'Degrees of freedom        = ', n1
       WRITE (nout,99998) 'Two tail probability      = ', p

99999  FORMAT (4X,8F5.1)
99998  FORMAT (1X,A,F8.4)
99997  FORMAT (1X,A,I8)
    END PROGRAM g08agfe

Fortranによるサンプルソースコード : 使用ルーチン名：g08agf

概要

入力データ

出力結果

ソースコード