von Mises分布から疑似乱数ベクトルを生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > von Mises分布から疑似乱数ベクトルを生成

Keyword: von Mises分布, 疑似乱数ベクトル

概要

本サンプルはvon Mises分布から疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。本サンプルは以下に示される確率密度関数をもつ、κ=1.0のvon Mises分布から5個の疑似乱数を生成し出力します。

von Mises分布のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05srf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05srf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はg05srf のマニュアルページを参照）

このデータをダウンロード

G05SRF Example Program Data
1  1  1762543     :: GENID,SUBID,SEED(1)
5 3               :: N,NMIX
1.0               :: VK

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に生成される疑似乱数の数（n=5）を指定しています。
４行目にvon Mises分布の集中度パラメータ（vk=1.0）を指定しています。

出力結果

（本ルーチンの詳細はg05srf のマニュアルページを参照）

この出力例をダウンロード

 G05SRF Example Program Results

     1.2947
    -1.9542
    -0.6464
    -1.4172
     1.2536

３～７行目に生成された疑似乱数が出力されています。

ソースコード

（本ルーチンの詳細はg05srf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05srfe

!      G05SRF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05srf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: vk
       INTEGER                         :: genid, ifail, lstate, n, subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: x(:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'G05SRF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size
       READ (nin,*) n

       ALLOCATE (x(n))

!      Read in the distribution parameters
       READ (nin,*) vk

!      Generate the variates
       ifail = 0
       CALL g05srf(n,vk,state,x,ifail)

!      Display the variates
       WRITE (nout,99999) x(1:n)

99999  FORMAT (1X,F10.4)
    END PROGRAM g05srfe

Fortranによるサンプルソースコード : 使用ルーチン名：g05srf

概要

入力データ

出力結果

ソースコード