ポワソン分布から整数疑似乱数ベクトルを生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > ポワソン分布から整数疑似乱数ベクトルを生成

Keyword: ポワソン分布, 整数疑似乱数ベクトル

概要

本サンプルはポワソン分布から整数疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。本サンプルは確率が以下で表される、平均λ=20のポワソン分布から10個の整数疑似乱数を生成し出力します。

ポワソン分布のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05tjf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05tjf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はg05tjf のマニュアルページを参照）

このデータをダウンロード

G05TJF Example Program Data
1  1  1762543     :: GENID,SUBID,SEED(1)
10                :: N
20.0              :: LAMBDA

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に生成される疑似乱数の数（n=10）を指定しています。
４行目にポワソン分布の平均（lambda=20.0）を指定しています。

出力結果

（本ルーチンの詳細はg05tjf のマニュアルページを参照）

この出力例をダウンロード

 G05TJF Example Program Results

           21
           15
           23
           24
           14
           20
           19
           23
           20
           22

３～１２行目に生成された整数疑似乱数が出力されています。

ソースコード

（本ルーチンの詳細はg05tjf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05tjfe

!      G05TJF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05tjf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, maxlr = 5000, nin = 5,    &
                                          nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: lambda
       INTEGER                         :: genid, ifail, lr, lstate, mode, n,   &
                                          subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: r(:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:), x(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          int, sqrt
!      .. Executable Statements ..
       WRITE (nout,*) 'G05TJF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size
       READ (nin,*) n

!      Read in the distribution parameters
       READ (nin,*) lambda

!      Use suggested value for LR
       lr = int(3.0E1_nag_wp+2.0E1_nag_wp*sqrt(lambda)+lambda)

!      If R is a reasonable size use MODE = 2
!      else do not reference R and use MODE = 3
       IF (lr<maxlr) THEN
          mode = 2
       ELSE
          mode = 3
          lr = 0
       END IF

       ALLOCATE (x(n),r(lr))

!      Generate the variates
       ifail = 0
       CALL g05tjf(mode,n,lambda,r,lr,state,x,ifail)

!      Display the variates
       WRITE (nout,99999) x(1:n)

99999  FORMAT (1X,I12)
    END PROGRAM g05tjfe

ポワソン分布から整数疑似乱数ベクトルを生成

Fortranによるサンプルソースコード : 使用ルーチン名：g05tjf

概要

入力データ

出力結果

ソースコード