Keyword: 一般離散分布, 整数疑似乱数ベクトル
概要
本サンプルは一般離散分布から整数疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。 本サンプルは確率密度関数が以下で表される一般離散分布から20個の整数疑似乱数を生成し出力します。
※本サンプルはnAG Fortranライブラリに含まれるルーチン g05tdf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05tdf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで
入力データ
（本ルーチンの詳細はg05tdf のマニュアルページを参照）| このデータをダウンロード |
G05TDF Example Program Data 1 1 1762543 :: GENID,SUBID,SEED(1) 20 :: N 11 -5 1 :: NP,IP1,ITYPE 0.01 0.02 0.04 0.08 0.2 0.3 0.2 0.08 0.04 0.02 0.01 :: End of P
- １行目はタイトル行で読み飛ばされます。
- ２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
- ３行目に生成される疑似乱数の数（n=20）を指定しています。
- ４行目に離散分布の確率密度関数または累積分布関数を定義するpの値の数（np=11）、p(1)の確率に対応する変量（ip1=-5）、pに含まれる情報の種類（itype=1:確率密度関数）を指定しています。
- ５〜６行目に確率密度関数の値(p)を指定しています。
出力結果
（本ルーチンの詳細はg05tdf のマニュアルページを参照）- ３〜２２行目に生成された疑似乱数が出力されています。
ソースコード
（本ルーチンの詳細はg05tdf のマニュアルページを参照）
※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法
| このソースコードをダウンロード |
PROGRAM g05tdfe
! G05TDF Example Program Text
! Mark 23 Release. nAG Copyright 2011.
! .. Use Statements ..
USE nag_library, ONLY : g05kff, g05tdf, nag_wp
! .. Implicit None Statement ..
IMPLICIT NONE
! .. Parameters ..
INTEGER, PARAMETER :: lseed = 1, nin = 5, nout = 6
! .. Local Scalars ..
INTEGER :: genid, ifail, ip1, itype, lr, &
lstate, mode, n, np, subid
! .. Local Arrays ..
REAL (KIND=nag_wp), ALLOCATABLE :: p(:), r(:)
INTEGER :: seed(lseed)
INTEGER, ALLOCATABLE :: state(:), x(:)
! .. Intrinsic Functions ..
INTRINSIC ceiling, real
! .. Executable Statements ..
WRITE (nout,*) 'G05TDF Example Program Results'
WRITE (nout,*)
! Skip heading in data file
READ (nin,*)
! Read in the base generator information and seed
READ (nin,*) genid, subid, seed(1)
! Initial call to initialiser to get size of STATE array
lstate = 0
ALLOCATE (state(lstate))
ifail = 0
CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)
! Reallocate STATE
DEALLOCATE (state)
ALLOCATE (state(lstate))
! Initialize the generator to a repeatable sequence
ifail = 0
CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)
! Read in sample size
READ (nin,*) n
! Read in the distribution parameters
READ (nin,*) np, ip1, itype
! Use suggested value for LR
lr = 10 + ceiling(1.4E0_nag_wp*real(np,kind=nag_wp))
! Generate and set up reference vector in one go
mode = 2
ALLOCATE (p(np),x(n),r(lr))
! Read in probabilities
READ (nin,*) p(1:np)
! Generate the variates
ifail = 0
CALL g05tdf(mode,n,p,np,ip1,itype,r,lr,state,x,ifail)
! Display the variates
WRITE (nout,99999) x(1:n)
99999 FORMAT (1X,I12)
END PROGRAM g05tdfe