Dirichlet分布から疑似乱数ベクトルを生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > Dirichlet分布から疑似乱数ベクトルを生成

Keyword: Dirichlet分布, 疑似乱数ベクトル

概要

本サンプルはDirichlet分布から疑似乱数ベクトルの生成を行うFortranによるサンプルプログラムです。本サンプルは以下に示される確率密度関数で m（次元）=4 かつ α={2.0,2.0,2.0,2.0} の場合のDirichlet分布から5個の疑似乱数を生成し出力します。

Dirichlet分布のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05sef() のExampleコードです。本サンプル及びルーチンの詳細情報は g05sef のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はg05sef のマニュアルページを参照）

このデータをダウンロード

G05SEF Example Program Data
1  1  1762543     :: GENID,SUBID,SEED(1)
5 4               :: N,M
2.0 2.0 2.0 2.0   :: A

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に生成される乱数の数（n=5）と次元の数（m=4）を指定しています。
４行目にDirichlet分布のパラメータ(a)を指定しています。

出力結果

（本ルーチンの詳細はg05sef のマニュアルページを参照）

この出力例をダウンロード

 G05SEF Example Program Results

          1       2       3       4
 1   0.3600  0.3138  0.0837  0.2426
 2   0.2874  0.5121  0.1497  0.0509
 3   0.2286  0.2190  0.3959  0.1566
 4   0.1744  0.3961  0.2764  0.1530
 5   0.1522  0.2845  0.2074  0.3559

４～８行目に生成された疑似乱数が出力されています。

ソースコード

（本ルーチンの詳細はg05sef のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05sefe

!      G05SEF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05sef, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: genid, ifail, ldx, lstate, m, n, subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: a(:), x(:,:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'G05SEF Example Program Results'
       WRITE (nout,*)
       FLUSH (nout)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size and number of dimensions
       READ (nin,*) n, m

       ldx = n
       ALLOCATE (x(ldx,m),a(m))

!      Read in the distribution parameters
       READ (nin,*) a(1:m)

!      Generate the variates
       ifail = 0
       CALL g05sef(n,m,a,state,x,ldx,ifail)

!      Display the variates
       ifail = 0
       CALL x04caf('General',' ',n,m,x,ldx,' ',ifail)

    END PROGRAM g05sefe

Fortranによるサンプルソースコード : 使用ルーチン名：g05sef

概要

入力データ

出力結果

ソースコード