Keyword: Gaussian copula, 疑似乱数
概要
本サンプルはGaussian copulaから疑似乱数行列の生成を行うFortranによるサンプルプログラムです。 本サンプルは以下に示される共分散行列をもつGaussian copulaから10個の疑似乱数を生成し出力します。
※本サンプルはnAG Fortranライブラリに含まれるルーチン g05rdf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05rdf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで
入力データ
（本ルーチンの詳細はg05rdf のマニュアルページを参照）| このデータをダウンロード |
G05RDF Example Program Data
1 1 1762543 :: GENID,SUBID,SEED(1)
10 4 :: N,M
1.69 0.39 -1.86 0.07
98.01 -7.07 -0.71
11.56 0.03
0.01 :: End of C (upper triangular part)
- １行目はタイトル行で読み飛ばされます。
- ２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
- ３行目に生成される疑似乱数の数（n=10）と分布の次元（m=4）を指定しています。
- ４〜７行目に分布の共分散行列の上三角部分(c)を指定しています。
出力結果
（本ルーチンの詳細はg05rdf のマニュアルページを参照）| この出力例をダウンロード |
G05RDF Example Program Results
Variates
1 2 3 4
1 0.6364 0.0517 0.4137 0.8817
2 0.1065 0.2461 0.7993 0.3806
3 0.7460 0.6313 0.2708 0.5421
4 0.7983 0.0564 0.6868 0.9234
5 0.1046 0.5790 0.8533 0.2208
6 0.4925 0.2784 0.3513 0.5158
7 0.3843 0.2349 0.9472 0.7801
8 0.7871 0.9941 0.9403 0.2044
9 0.4982 0.9015 0.7176 0.2914
10 0.6717 0.5359 0.5961 0.4487
- ５〜１４行目に生成された疑似乱数が出力されています。
ソースコード
（本ルーチンの詳細はg05rdf のマニュアルページを参照）
※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法
| このソースコードをダウンロード |
PROGRAM g05rdfe
! G05RDF Example Program Text
! Mark 23 Release. nAG Copyright 2011.
! .. Use Statements ..
USE nag_library, ONLY : g05kff, g05rdf, nag_wp, x04caf
! .. Implicit None Statement ..
IMPLICIT NONE
! .. Parameters ..
INTEGER, PARAMETER :: lseed = 1, nin = 5, nout = 6
! .. Local Scalars ..
INTEGER :: genid, i, ifail, ldc, ldx, lr, &
lstate, m, mode, n, subid
! .. Local Arrays ..
REAL (KIND=nag_wp), ALLOCATABLE :: c(:,:), r(:), x(:,:)
INTEGER :: seed(lseed)
INTEGER, ALLOCATABLE :: state(:)
! .. Executable Statements ..
WRITE (nout,*) 'G05RDF Example Program Results'
WRITE (nout,*)
FLUSH (nout)
! Skip heading in data file
READ (nin,*)
! Read in the base generator information and seed
READ (nin,*) genid, subid, seed(1)
! Initial call to initialiser to get size of STATE array
lstate = 0
ALLOCATE (state(lstate))
ifail = 0
CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)
! Reallocate STATE
DEALLOCATE (state)
ALLOCATE (state(lstate))
! Initialize the generator to a repeatable sequence
ifail = 0
CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)
! Read in sample size and number of dimensions
READ (nin,*) n, m
ldc = m
ldx = n
lr = m*(m+1) + 1
ALLOCATE (c(ldc,m),x(ldx,m),r(lr))
! Read in upper triangle portion of the covariance matrix
DO i = 1, m
READ (nin,*) c(i,i:m)
END DO
! Using a single call to G05RDF, so set up reference vector
! and generate values in one go
mode = 2
! Generate variates
ifail = 0
CALL g05rdf(mode,n,m,c,ldc,r,lr,state,x,ldx,ifail)
! Display variates
ifail = 0
CALL x04caf('General',' ',n,m,x,ldx,'Variates',ifail)
END PROGRAM g05rdfe