二変量Plackett copulaから疑似乱数行列を生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > 二変量Plackett copulaから疑似乱数行列を生成

Keyword: 二変量, Plackett copula, 疑似乱数

概要

本サンプルは二変量Plackett copulaから疑似乱数行列の生成を行うFortranによるサンプルプログラムです。本サンプルは以下の式で表されるPlackett copulaのC_2.0の分布をもつ13の２変量疑似乱数を生成し出力します。

plackettのデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05rgf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05rgf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はg05rgf のマニュアルページを参照）

このデータをダウンロード

G05RGF Example Program Data
1  1  1762543          :: GENID,SUBID,SEED(1)
13  1                  :: N,SORDER
2.0                    :: THETA

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に生成される２変量の数（n=13）と変量の格納順（sorder=1:x(i,j)）を指定しています。
４行目にcopulaのパラメータ（theta=-2.0）を指定しています。

出力結果

（本ルーチンの詳細はg05rgf のマニュアルページを参照）

この出力例をダウンロード

 G05RGF Example Program Results

 Uniform variates with copula joint distribution
           1       2
  1   0.6364  0.0695
  2   0.1065  0.4586
  3   0.7460  0.3586
  4   0.7983  0.3267
  5   0.1046  0.9888
  6   0.4925  0.8920
  7   0.3843  0.4903
  8   0.7871  0.4248
  9   0.4982  0.5783
 10   0.6717  0.4419
 11   0.0505  0.5802
 12   0.2580  0.6629
 13   0.6238  0.3291

４～１７行目に生成された疑似乱数が出力されています。

ソースコード

（本ルーチンの詳細はg05rgf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05rgfe

!      G05RGF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05rgf, nag_wp, x04caf
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: theta
       INTEGER                         :: genid, ifail, ldx, lstate, n, sdx,   &
                                          sorder, subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: x(:,:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:)
!      .. Executable Statements ..
       WRITE (nout,*) 'G05RGF Example Program Results'
       WRITE (nout,*)
       FLUSH (nout)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size and order
       READ (nin,*) n, sorder

       IF (sorder==1) THEN
!         X(N,2)
          ldx = n
          sdx = 2
       ELSE
!         X(2,N)
          ldx = 2
          sdx = n
       END IF
       ALLOCATE (x(ldx,sdx))

!      Read in parameter
       READ (nin,*) theta

!      Generate variates
       ifail = 0
       CALL g05rgf(n,theta,sorder,state,x,ldx,sdx,ifail)

!      Display the variates
       IF (sorder==1) THEN
!         X(N,2)
          ifail = 0
          CALL x04caf('General',' ',n,2,x,ldx, &
             'Uniform variates with copula joint distribution',ifail)
       ELSE
!         X(2,N)
          ifail = 0
          CALL x04caf('General',' ',2,n,x,ldx, &
             'Uniform variates with copula joint distribution',ifail)
       END IF

    END PROGRAM g05rgfe

Fortranによるサンプルソースコード : 使用ルーチン名：g05rgf

概要

入力データ

出力結果

ソースコード