ARMAモデルの時系列の実現値の生成

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > ARMAモデルの時系列の実現値の生成

Keyword: ARMA, 時系列, 実現値

概要

本サンプルはARMAモデルの時系列の実現値の生成を行うFortranによるサンプルプログラムです。本サンプルは以下の式で示されるARMAモデルに対して10個の観測値を生成し出力します。

ARMAモデルのデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン g05phf() のExampleコードです。本サンプル及びルーチンの詳細情報は g05phf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はg05phf のマニュアルページを参照）

このデータをダウンロード

G05PHF Example Program Data
1  1  1762543     :: GENID,SUBID,SEED(1)
10                :: N
2  0              :: IP,IQ
0.0               :: XMEAN
0.4  0.2          :: PHI
1.0               :: AVAR

１行目はタイトル行で読み飛ばされます。
２行目に使用する生成器（genid=1:nAG基本生成器）、生成器に関する情報（subid=1:GENIDが1の場合この値は参照されません）、生成器の初期値（seed=1762543）を指定しています。
３行目に生成される観測値数（n=10）を指定しています。
４行目に自己回帰係数pの数（ip=2）と移動平均係数qの数（iq=0）を指定しています。
５行目に時系列の平均（xmean=0.0）を指定しています。
６行目にモデルの自己回帰係数(phi)を指定しています。
７行目に正規摂動の分散(avar)を指定しています。

出力結果

（本ルーチンの詳細はg05phf のマニュアルページを参照）

この出力例をダウンロード

 G05PHF Example Program Results

      -1.7103
      -0.4042
      -0.1845
      -1.5004
      -1.1946
      -1.8184
      -1.0895
       1.6408
       1.3555
       1.1908

３～１２行目に生成された10個の観測値が出力されています。

ソースコード

（本ルーチンの詳細はg05phf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM g05phfe

!      G05PHF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : g05kff, g05phf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: lseed = 1, nin = 5, nout = 6
!      .. Local Scalars ..
       REAL (KIND=nag_wp)              :: avar, var, xmean
       INTEGER                         :: genid, ifail, ip, iq, lr, lstate,    &
                                          mode, n, subid
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: phi(:), r(:), theta(:), x(:)
       INTEGER                         :: seed(lseed)
       INTEGER, ALLOCATABLE            :: state(:)
!      .. Intrinsic Functions ..
       INTRINSIC                          max
!      .. Executable Statements ..
       WRITE (nout,*) 'G05PHF Example Program Results'
       WRITE (nout,*)

!      Skip heading in data file
       READ (nin,*)

!      Read in the base generator information and seed
       READ (nin,*) genid, subid, seed(1)

!      Initial call to initialiser to get size of STATE array
       lstate = 0
       ALLOCATE (state(lstate))
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Reallocate STATE
       DEALLOCATE (state)
       ALLOCATE (state(lstate))

!      Initialize the generator to a repeatable sequence
       ifail = 0
       CALL g05kff(genid,subid,seed,lseed,state,lstate,ifail)

!      Read in sample size
       READ (nin,*) n

!      Read in number of coefficients
       READ (nin,*) ip, iq

       lr = ip + iq + 6 + max(ip,iq+1)
       ALLOCATE (phi(ip),theta(iq),x(n),r(lr))

!      Read in mean
       READ (nin,*) xmean

!      Read in autoregressive coefficients
       IF (ip>0) THEN
          READ (nin,*) phi(1:ip)
       END IF

!      Read in moving average coefficients
       IF (iq>0) THEN
          READ (nin,*) theta(1:iq)
       END IF

!      Read in variance
       READ (nin,*) avar

!      Using a single call to G05PHF, so set up reference vector
!      and generate values in one go
       mode = 2

       ifail = 0
       CALL g05phf(mode,n,xmean,ip,phi,iq,theta,avar,r,lr,state,var,x,ifail)

!      Display the variates
       WRITE (nout,99999) x(1:n)

99999  FORMAT (1X,F12.4)
    END PROGRAM g05phfe

Fortranによるサンプルソースコード : 使用ルーチン名：g05phf

概要

入力データ

出力結果

ソースコード