１次元離散ウェーブレット変換

ホーム > 製品 > nAG数値計算ライブラリ > nAG Fortranライブラリ > サンプルソースコード集 > １次元離散ウェーブレット変換

Keyword: １次元, 離散, ウェーブレット変換

概要

本サンプルは１次元離散ウェーブレット変換を行うFortranによるサンプルプログラムです。本サンプルは以下に示される８個の要素をもつ配列についてDaubechies ウェーブレットを用いて１次元離散ウェーブレット変換を行い、近似係数、詳細係数とウェーブレットの再構成を出力します。

１次元離散ウェーブレット変換のデータ　

※本サンプルはnAG Fortranライブラリに含まれるルーチン c09caf() のExampleコードです。本サンプル及びルーチンの詳細情報は c09caf のマニュアルページをご参照ください。
ご相談やお問い合わせはこちらまで

入力データ

（本ルーチンの詳細はc09caf のマニュアルページを参照）

このデータをダウンロード

C09CAF Example Program Data
 8              : n
 DB4  Zero      : wavnam, mode
 1.0
 3.0
 5.0
 7.0
 6.0
 4.0
 5.0
 2.0            : x(1:n)

１行目はタイトル行で読み飛ばされます。
２行目に入力データである配列の要素の数(n)を指定しています。
３行目にどのウェーブレット法を使用するかを示すパラメータ（wavnam=DB4）とデータの端部拡張（End Extension）の手法を示すパラメータ（mode=Zero）を指定しています。この場合"DB4"は４つの消失モーメントがある Daubechies ウェーブレットを使用することを意味し、"Zero"はデータの端部をゼロパディング（ゼロ詰め）することを意味します。
４～１１行目に配列の要素(x)を指定しています。

出力結果

（本ルーチンの詳細はc09caf のマニュアルページを参照）

この出力例をダウンロード

 C09CAF Example Program Results
 DWT :: Wavelet: DB4         , End mode: Zero        
 Input Data      X :
   1.0000   3.0000   5.0000   7.0000   6.0000   4.0000   5.0000   2.0000
 Approximation coefficients CA : 
   0.0011  -0.0043  -0.0174   4.4778   8.9557   7.3401   2.5816
 Detail coefficients        CD : 
   0.0237   0.0410  -0.5966   1.7763  -0.7517   0.3332  -0.1188
 Reconstruction              Y : 
   1.0000   3.0000   5.0000   7.0000   6.0000   4.0000   5.0000   2.0000

２行目にウェーブレット変換の手法とデータの端部拡張（End Extension）のモードが出力されています。
４行目に入力データである配列の要素が出力されています。
６行目に近似係数が出力されています。
８行目に詳細係数が出力されています。
１０行目にウェーブレット再構成が出力されています。

ソースコード

（本ルーチンの詳細はc09caf のマニュアルページを参照）

※本サンプルソースコードは科学技術・統計計算ライブラリである「nAG Fortranライブラリ」のルーチンを呼び出します。
サンプルのコンパイル及び実行方法

このソースコードをダウンロード

    PROGRAM c09cafe

!      C09CAF Example Program Text

!      Mark 23 Release. nAG Copyright 2011.

!      .. Use Statements ..
       USE nag_library, ONLY : c09aaf, c09caf, c09cbf, nag_wp
!      .. Implicit None Statement ..
       IMPLICIT NONE
!      .. Parameters ..
       INTEGER, PARAMETER              :: nin = 5, nout = 6
!      .. Local Scalars ..
       INTEGER                         :: ifail, n, nf, nwc, nwl, ny
       CHARACTER (12)                  :: mode, wavnam, wtrans
!      .. Local Arrays ..
       REAL (KIND=nag_wp), ALLOCATABLE :: ca(:), cd(:), x(:), y(:)
       INTEGER                         :: icomm(100)
!      .. Executable Statements ..
       WRITE (nout,*) 'C09CAF Example Program Results'
!      Skip heading in data file
       READ (nin,*)
!      Read problem parameters.
       READ (nin,*) n
       READ (nin,*) wavnam, mode
       ALLOCATE (x(n),y(n))

       WRITE (nout,99999) wavnam, mode
!      Read array
       READ (nin,*) x(1:n)
       WRITE (nout,*) 'Input Data      X :'
       WRITE (nout,99997) x(1:n)
!      Query wavelet filter dimensions
       wtrans = 'Single Level'

!         ifail: behaviour on error exit   
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
       ifail = 0
       CALL c09aaf(wavnam,wtrans,mode,n,nwl,nf,nwc,icomm,ifail)

       ALLOCATE (ca(nwc),cd(nwc))

       ifail = 0
       CALL c09caf(n,x,nwc,ca,cd,icomm,ifail)

       WRITE (nout,99998)
       WRITE (nout,99997) ca(1:nwc)
       WRITE (nout,99996)
       WRITE (nout,99997) cd(1:nwc)

       ny = n

       ifail = 0
       CALL c09cbf(nwc,ca,cd,ny,y,icomm,ifail)

       WRITE (nout,99995)
       WRITE (nout,99997) y(1:ny)

99999  FORMAT (1X,'DWT :: Wavelet: ',A,', End mode: ',A)
99998  FORMAT (1X,'Approximation coefficients CA : ')
99997  FORMAT (1X,8(F8.4,1X):)
99996  FORMAT (1X,'Detail coefficients        CD : ')
99995  FORMAT (1X,'Reconstruction              Y : ')
    END PROGRAM c09cafe

Fortranによるサンプルソースコード : 使用ルーチン名：c09caf

概要

入力データ

出力結果

ソースコード