概要
本サンプルはFortran言語によりLAPACKルーチンZTRCONを利用するサンプルプログラムです。
入力データ
（本ルーチンの詳細はZTRCON のマニュアルページを参照）| このデータをダウンロード |
ZTRCON Example Program Data 4 :Value of N 'L' :Value of UPLO ( 4.78, 4.56) ( 2.00,-0.30) (-4.11, 1.25) ( 2.89,-1.34) ( 2.36,-4.25) ( 4.15, 0.80) (-1.89, 1.15) ( 0.04,-3.69) (-0.02, 0.46) ( 0.33,-0.26) :End of matrix A
出力結果
（本ルーチンの詳細はZTRCON のマニュアルページを参照）ソースコード
（本ルーチンの詳細はZTRCON のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program ztrcon_example
! ZTRCON Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_interfaces, Only: ztrcon
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: diag = 'N', norm = '1'
! .. Local Scalars ..
Real (Kind=dp) :: rcond
Integer :: i, info, lda, n
Character (1) :: uplo
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: a(:, :), work(:)
Real (Kind=dp), Allocatable :: rwork(:)
! .. Intrinsic Procedures ..
Intrinsic :: epsilon
! .. Executable Statements ..
Write (nout, *) 'ZTRCON Example Program Results'
! Skip heading in data file
Read (nin, *)
Read (nin, *) n
lda = n
Allocate (a(lda,n), work(2*n), rwork(n))
! Read A from data file
Read (nin, *) uplo
If (uplo=='U') Then
Read (nin, *)(a(i,i:n), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)(a(i,1:i), i=1, n)
End If
! Estimate condition number
Call ztrcon(norm, uplo, diag, n, a, lda, rcond, work, rwork, info)
Write (nout, *)
If (rcond>=epsilon(1.0E0_dp)) Then
Write (nout, 100) 'Estimate of condition number =', 1.0_dp/rcond
Else
Write (nout, *) 'A is singular to working precision'
End If
100 Format (1X, A, 1P, E10.2)
End Program