計算ルーチン: 複素三角行列の逆行列 : (Rectangular Full Packed フォーマット)

ZTFTRI Example Program Data
   4     'L'     'N'     'N'  : n, uplo, transr, diag
 ( 4.15,-0.80)  (-0.02,-0.46)
 ( 4.78, 4.56)  ( 0.33, 0.26)
 ( 2.00,-0.30)  (-4.11, 1.25)
 ( 2.89,-1.34)  ( 2.36,-4.25)
 (-1.89, 1.15)  ( 0.04,-3.69) : AR

 ZTFTRI Example Program Results

 Inverse
                    1                 2                 3                 4
 1  ( 0.1095,-0.1045)
 2  ( 0.0582,-0.0411) (-0.2227,-0.0677)
 3  ( 0.0032, 0.1905) ( 0.1538,-0.2192) ( 0.2323,-0.0448)
 4  ( 0.7602, 0.2814) ( 1.6184,-1.4346) ( 0.1289,-0.2250) ( 1.8697, 1.4731)

    Program ztftri_example

!     ZTFTRI Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: ztftri, ztfttr
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, k, lar1, lda, lenar, n, q
      Character (1) :: diag, transr, uplo
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: a(:, :), ar(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZTFTRI Example Program Results'
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, uplo, transr, diag

      lenar = n*(n+1)/2
      lda = n
      Allocate (ar(1:lenar), a(lda,n))

!     Setup notional dimensions of RFP matrix AR
      k = n/2
      q = n - k
      If (transr=='N' .Or. transr=='n') Then
        lar1 = 2*k + 1
      Else
        lar1 = q
      End If

!     Read an RFP matrix into array AR
      Do i = 1, lar1
        Read (nin, *) ar(i:lenar:lar1)
      End Do

!     Compute inverse of A
      Call ztftri(transr, uplo, diag, n, ar, info)

      Write (nout, *)
      Flush (nout)
      If (info==0) Then

!       Convert and print inverse
        Call ztfttr(transr, uplo, n, ar, a, lda, info)
        ifail = 0

        Call nagf_file_print_matrix_complex_gen_comp(uplo, 'Nonunit', n, n, a, &
          lda, 'Bracketed', 'F7.4', 'Inverse', 'Integer', rlabs, 'Integer', &
          clabs, 80, 0, ifail)
      Else
        Write (nout, *) 'A is singular'
      End If

    End Program