複素線形方程式: 対称行列 : (右辺はベクトル)

LAPACKサンプルソースコード : 使用ルーチン名：ZSYSV

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > 対称行列

概要

本サンプルはFortran言語によりLAPACKルーチンZSYSVを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A x = b, \end{displaymath}

$ A$は複素対称行列です。

\begin{displaymath} A = \left( \begin{array}{cccc} -0.56 + 0.12 i & -1.54 - 2... ...- 2.96 i & 5.14 - 0.64 i & -0.39 - 0.71 i \end{array} \right) \end{displaymath}

及び

\begin{displaymath} b = \left( \begin{array}{c} -6.43 + 19.24 i \\ -0.49 - ... ... -48.18 + 66.00 i \\ -55.64 + 41.22 i \end{array} \right). \end{displaymath}

$ A$の分解についての詳細も合わせて出力されます。

入力データ

（本ルーチンの詳細はZSYSV のマニュアルページを参照）
このデータをダウンロード 
ZSYSV Example Program Data
    4                                                            :Value of N
 ( -0.56,  0.12) ( -1.54, -2.86) (  5.32, -1.59) (  3.80,  0.92)
                 ( -2.83 ,-0.03) ( -3.52,  0.58) ( -7.86, -2.96)
                                 (  8.86,  1.81) (  5.14, -0.64)
                                                 ( -0.39 ,-0.71) :End matrix A
 ( -6.43, 19.24) ( -0.49, -1.47) (-48.18, 66.00) (-55.64, 41.22) :End vector b

出力結果

（本ルーチンの詳細はZSYSV のマニュアルページを参照）
この出力例をダウンロード 
 ZSYSV Example Program Results

 Solution
    (-4.0000, 3.0000) ( 3.0000,-2.0000) (-2.0000, 5.0000) ( 1.0000,-1.0000) 

 Details of the factorization
                    1                 2                 3                 4
 1  (-2.0954,-2.2011) (-0.1071,-0.3157) (-0.4823, 0.0150) ( 0.4426, 0.1936)
 2                    ( 4.4079, 5.3991) (-0.6078, 0.2811) ( 0.5279,-0.3715)
 3                                      (-2.8300,-0.0300) (-7.8600,-2.9600)
 4                                                        (-0.3900,-0.7100)

 Pivot indices
           1          2         -2         -2

ソースコード

（本ルーチンの詳細はZSYSV のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zsysv_example

!     ZSYSV Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zsysv
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, lda, lwork, n
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: a(:, :), b(:), work(:)
      Integer, Allocatable :: ipiv(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZSYSV Example Program Results'
      Write (nout, *)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n
      lda = n
      lwork = nb*n
      Allocate (a(lda,n), b(n), work(lwork), ipiv(n))

!     Read the upper triangular part of the matrix A from data file

      Read (nin, *)(a(i,i:n), i=1, n)

!     Read b from data file

      Read (nin, *) b(1:n)

!     Solve the equations Ax = b for x

      Call zsysv('Upper', n, 1, a, lda, ipiv, b, n, work, lwork, info)

      If (info==0) Then

!       Print solution

        Write (nout, *) 'Solution'
        Write (nout, 100) b(1:n)

!       Print details of factorization

        Write (nout, *)
        Flush (nout)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('Upper', &
          'Non-unit diagonal', n, n, a, lda, 'Bracketed', 'F7.4', &
          'Details of the factorization', 'Integer', rlabs, 'Integer', clabs, &
          80, 0, ifail)

!       Print pivot indices

        Write (nout, *)
        Write (nout, *) 'Pivot indices'
        Write (nout, 110) ipiv(1:n)

      Else
        Write (nout, 120) 'The diagonal block ', info, ' of D is zero'
      End If

100   Format ((4X,4('(',F7.4,',',F7.4,') ')))
110   Format (1X, 7I11)
120   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks