計算ルーチン: ZPTTRFで L×D×L′分解済みの結果を用いて複素エルミート正定値三重対角連立方程式を解く

ZPTTRS Example Program Data
    4             2                                      :Values of N and NRHS
               ( 16.0,-16.0) ( 18.0,  9.0) (  1.0,  4.0) :End of superdiagonal E
   16.0          41.0          46.0          21.0        :End of diagonal D
 ( 64.0, 16.0) (-16.0,-32.0)
 ( 93.0, 62.0) ( 61.0,-66.0)
 ( 78.0,-80.0) ( 71.0,-74.0)
 ( 14.0,-27.0) ( 35.0, 15.0)                             :End of matrix B

 ZPTTRS Example Program Results

 Solution(s)
                            1                         2
 1  (     2.0000,     1.0000) (    -3.0000,    -2.0000)
 2  (     1.0000,     1.0000) (     1.0000,     1.0000)
 3  (     1.0000,    -2.0000) (     1.0000,    -2.0000)
 4  (     1.0000,    -1.0000) (     2.0000,     1.0000)

    Program zpttrs_example

!     ZPTTRS Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zpttrf, zpttrs
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
      Character (1), Parameter :: uplo = 'U'
!     .. Local Scalars ..
      Integer :: i, ifail, info, ldb, n, nrhs
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: b(:, :), e(:)
      Real (Kind=dp), Allocatable :: d(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZPTTRS Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, nrhs
      ldb = n
      Allocate (b(ldb,nrhs), e(n-1), d(n))

!     Read the upper bidiagonal part of the tridiagonal matrix A from
!     data file

      Read (nin, *) e(1:n-1)
      Read (nin, *) d(1:n)

!     Read the right hand matrix B

      Read (nin, *)(b(i,1:nrhs), i=1, n)

!     Factorize the tridiagonal matrix A
      Call zpttrf(n, d, e, info)

      If (info==0) Then

!       Solve the equations AX = B
        Call zpttrs(uplo, n, nrhs, d, e, b, ldb, info)

!       Print the solution

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
          b, ldb, 'Bracketed', ' ', 'Solution(s)', 'Integer', rlabs, &
          'Integer', clabs, 80, 0, ifail)

      Else
        Write (nout, 100) 'The leading minor of order ', info, &
          ' is not positive definite'
      End If

100   Format (1X, A, I3, A)
    End Program