概要
本サンプルはFortran言語によりLAPACKルーチンZPPCONを利用するサンプルプログラムです。
入力データ
（本ルーチンの詳細はZPPCON のマニュアルページを参照）| このデータをダウンロード |
ZPPCON Example Program Data 4 :Value of N 'L' :Value of UPLO (3.23, 0.00) (1.51, 1.92) ( 3.58, 0.00) (1.90,-0.84) (-0.23,-1.11) ( 4.09, 0.00) (0.42,-2.50) (-1.18,-1.37) ( 2.33, 0.14) ( 4.29, 0.00) :End of matrix A
出力結果
（本ルーチンの詳細はZPPCON のマニュアルページを参照）ソースコード
（本ルーチンの詳細はZPPCON のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program zppcon_example
! ZPPCON Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_interfaces, Only: zlanhp, zppcon, zpptrf
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
! .. Local Scalars ..
Real (Kind=dp) :: anorm, rcond
Integer :: i, info, j, n
Character (1) :: uplo
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: ap(:), work(:)
Real (Kind=dp), Allocatable :: rwork(:)
! .. Intrinsic Procedures ..
Intrinsic :: epsilon
! .. Executable Statements ..
Write (nout, *) 'ZPPCON Example Program Results'
! Skip heading in data file
Read (nin, *)
Read (nin, *) n
Allocate (ap(n*(n+1)/2), work(2*n), rwork(n))
! Read A from data file
Read (nin, *) uplo
If (uplo=='U') Then
Read (nin, *)((ap(i+j*(j-1)/2),j=i,n), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ap(i+(2*n-j)*(j-1)/2),j=1,i), i=1, n)
End If
! Compute norm of A
anorm = zlanhp('1-norm', uplo, n, ap, rwork)
! Factorize A
Call zpptrf(uplo, n, ap, info)
Write (nout, *)
If (info==0) Then
! Estimate condition number
Call zppcon(uplo, n, ap, anorm, rcond, work, rwork, info)
If (rcond>=epsilon(1.0E0_dp)) Then
Write (nout, 100) 'Estimate of condition number =', 1.0_dp/rcond
Else
Write (nout, *) 'A is singular to working precision'
End If
Else
Write (nout, *) 'A is not positive definite'
End If
100 Format (1X, A, 1P, E10.2)
End Program