複素線形方程式: エルミート行列 : (右辺はベクトル)

LAPACKサンプルソースコード : 使用ルーチン名：ZHESV

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > エルミート行列

概要

本サンプルはFortran言語によりLAPACKルーチンZHESVを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A x = b, \end{displaymath}

$ A$はエルミート行列です。

\begin{displaymath} A = \left( \begin{array}{cccc} -1.84 & 0.11 - 0.11 i & -1... ...i & 2.21 - 0.21 i & 1.58 + 0.90 i & -1.36 \end{array} \right) \end{displaymath}

及び

\begin{displaymath} b = \left( \begin{array}{c} 2.98 - 10.18 i \\ -9.58 + 3... ... \\ -0.77 - 16.05 i \\ 7.79 + 5.48 i \end{array} \right). \end{displaymath}

$ A$の分解についてに詳細 も合わせて出力されます。

入力データ

（本ルーチンの詳細はZHESV のマニュアルページを参照）
このデータをダウンロード 
ZHESV Example Program Data
    4                                                            :Value of N
 ( -1.84,  0.00) (  0.11, -0.11) ( -1.78, -1.18) (  3.91, -1.50)
                 ( -4.63 , 0.00) ( -1.84,  0.03) (  2.21,  0.21)
                                 ( -8.87,  0.00) (  1.58, -0.90)
                                                 ( -1.36 , 0.00) :End matrix A
 (  2.98,-10.18) ( -9.58,  3.88) ( -0.77,-16.05) (  7.79,  5.48) :End vector b

出力結果

（本ルーチンの詳細はZHESV のマニュアルページを参照）
この出力例をダウンロード 
 ZHESV Example Program Results

 Solution
    ( 2.0000, 1.0000) ( 3.0000,-2.0000) (-1.0000, 2.0000) ( 1.0000,-1.0000)

 Details of the factorization
                    1                 2                 3                 4
 1  (-7.1028, 0.0000) ( 0.2997, 0.1578) ( 0.3397, 0.0303) (-0.1518, 0.3743)
 2                    (-5.4176, 0.0000) ( 0.5637, 0.2850) ( 0.3100, 0.0433)
 3                                      (-1.8400, 0.0000) ( 3.9100,-1.5000)
 4                                                        (-1.3600, 0.0000)

 Pivot indices
           1          2         -1         -1

ソースコード

（本ルーチンの詳細はZHESV のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zhesv_example

!     ZHESV Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zhesv
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, lda, lwork, n
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: a(:, :), b(:), work(:)
      Integer, Allocatable :: ipiv(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZHESV Example Program Results'
      Write (nout, *)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n
      lda = n
      lwork = nb*n
      Allocate (a(lda,n), b(n), work(lwork), ipiv(n))

!     Read the upper triangular part of the matrix A from data file

      Read (nin, *)(a(i,i:n), i=1, n)

!     Read b from data file

      Read (nin, *) b(1:n)

!     Solve the equations Ax = b for x
      Call zhesv('Upper', n, 1, a, lda, ipiv, b, n, work, lwork, info)

      If (info==0) Then

!       Print solution

        Write (nout, *) 'Solution'
        Write (nout, 100) b(1:n)

!       Print details of factorization

        Write (nout, *)
        Flush (nout)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('Upper', &
          'Non-unit diagonal', n, n, a, lda, 'Bracketed', 'F7.4', &
          'Details of the factorization', 'Integer', rlabs, 'Integer', clabs, &
          80, 0, ifail)

!       Print pivot indices

        Write (nout, *)
        Write (nout, *) 'Pivot indices'
        Write (nout, 110) ipiv(1:n)

      Else
        Write (nout, 120) 'The diagonal block ', info, ' of D is zero'
      End If

100   Format ((3X,4(' (',F7.4,',',F7.4,')',:)))
110   Format (1X, 7I11)
120   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks