複素線形方程式: 三重対角行列 : (右辺は行列)

LAPACKサンプルソースコード : 使用ルーチン名：ZGTSVX

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > 三重対角行列

概要

本サンプルはFortran言語によりLAPACKルーチンZGTSVXを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A X = B, \end{displaymath}

$ A$は三重対角行列です。

\begin{displaymath} A = \left( \begin{array}{ccccc} -1.3 + 1.3i & 2.0 - 1.0i ... ...\\ 0 & 0 & 0 & 1.0 + 1.0i & -3.3 + 1.3i \end{array} \right) \end{displaymath}

及び

\begin{displaymath} B = \left( \begin{array}{rr} 2.4 - 5.0i & 2.7 + 6.9i \\ ... ...9 + 9.3i \\ -1.0 + 1.6i & -3.0 + 12.2i \end{array} \right). \end{displaymath}

後方エラーと前方エラーの推定値及び条件数も合わせて出力されます。

入力データ

（本ルーチンの詳細はZGTSVX のマニュアルページを参照）
このデータをダウンロード 
ZGTSVX Example Program Data
   5    2                                                :Values of N and NRHS
 (  2.0, -1.0) (  2.0,  1.0) ( -1.0,  1.0) (  1.0, -1.0) :End of DU
 ( -1.3,  1.3) ( -1.3,  1.3) ( -1.3,  3.3) ( -0.3,  4.3)
 ( -3.3,  1.3)                                           :End of D
 (  1.0, -2.0) (  1.0 , 1.0) (  2.0, -3.0) (  1.0,  1.0) :End of  DL
 (  2.4, -5.0) (  2.7,  6.9)
 (  3.4, 18.2) ( -6.9, -5.3)
 (-14.7,  9.7) ( -6.0, -0.6)
 ( 31.9, -7.7) ( -3.9,  9.3)
 ( -1.0,  1.6) ( -3.0, 12.2)                             :End of B

出力結果

（本ルーチンの詳細はZGTSVX のマニュアルページを参照）
この出力例をダウンロード 
 ZGTSVX Example Program Results

 Solution(s)
                    1                 2
 1  ( 1.0000, 1.0000) ( 2.0000,-1.0000)
 2  ( 3.0000,-1.0000) ( 1.0000, 2.0000)
 3  ( 4.0000, 5.0000) (-1.0000, 1.0000)
 4  (-1.0000,-2.0000) ( 2.0000, 1.0000)
 5  ( 1.0000,-1.0000) ( 2.0000,-2.0000)

 Backward errors (machine-dependent)
       7.2E-17    6.7E-17

 Estimated forward error bounds (machine-dependent)
       5.6E-14    7.4E-14

 Estimate of reciprocal condition number
       5.4E-03

ソースコード

（本ルーチンの詳細はZGTSVX のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zgtsvx_example

!     ZGTSVX Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zgtsvx
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=dp) :: rcond
      Integer :: i, ifail, info, ldb, ldx, n, nrhs
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: b(:, :), d(:), df(:), dl(:), dlf(:), &
        du(:), du2(:), duf(:), work(:), x(:, :)
      Real (Kind=dp), Allocatable :: berr(:), ferr(:), rwork(:)
      Integer, Allocatable :: ipiv(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZGTSVX Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, nrhs
      ldb = n
      ldx = n
      Allocate (b(ldb,nrhs), d(n), df(n), dl(n-1), dlf(n-1), du(n-1), &
        du2(n-2), duf(n-1), work(2*n), x(ldx,nrhs), berr(nrhs), ferr(nrhs), &
        rwork(n), ipiv(n))

!     Read the tridiagonal matrix A from data file

      Read (nin, *) du(1:n-1)
      Read (nin, *) d(1:n)
      Read (nin, *) dl(1:n-1)

!     Read the right hand matrix B

      Read (nin, *)(b(i,1:nrhs), i=1, n)

!     Solve the equations AX = B
      Call zgtsvx('No factors', 'No transpose', n, nrhs, dl, d, du, dlf, df, &
        duf, du2, ipiv, b, ldb, x, ldx, rcond, ferr, berr, work, rwork, info)

      If ((info==0) .Or. (info==n+1)) Then

!       Print solution, error bounds and condition number

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
          x, ldx, 'Bracketed', 'F7.4', 'Solution(s)', 'Integer', rlabs, &
          'Integer', clabs, 80, 0, ifail)

        Write (nout, *)
        Write (nout, *) 'Backward errors (machine-dependent)'
        Write (nout, 100) berr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
        Write (nout, 100) ferr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimate of reciprocal condition number'
        Write (nout, 100) rcond

        If (info==n+1) Then
          Write (nout, *)
          Write (nout, *) 'The matrix A is singular to working precision'
        End If
      Else
        Write (nout, 110) 'The (', info, ',', info, ')', &
          ' element of the factor U is zero'
      End If

100   Format ((3X,1P,7E11.1))
110   Format (1X, A, I3, A, I3, A, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks