概要
本サンプルはFortran言語によりLAPACKルーチンZGECONを利用するサンプルプログラムです。
入力データ
（本ルーチンの詳細はZGECON のマニュアルページを参照）| このデータをダウンロード |
ZGECON Example Program Data 4 :Value of N (-1.34, 2.55) ( 0.28, 3.17) (-6.39,-2.20) ( 0.72,-0.92) (-0.17,-1.41) ( 3.31,-0.15) (-0.15, 1.34) ( 1.29, 1.38) (-3.29,-2.39) (-1.91, 4.42) (-0.14,-1.35) ( 1.72, 1.35) ( 2.41, 0.39) (-0.56, 1.47) (-0.83,-0.69) (-1.96, 0.67) :End of matrix A
出力結果
（本ルーチンの詳細はZGECON のマニュアルページを参照）ソースコード
（本ルーチンの詳細はZGECON のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program zgecon_example
! ZGECON Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_interfaces, Only: zgecon, zgetrf, zlange
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: norm = '1'
! .. Local Scalars ..
Real (Kind=dp) :: anorm, rcond
Integer :: i, info, lda, n
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: a(:, :), work(:)
Real (Kind=dp), Allocatable :: rwork(:)
Integer, Allocatable :: ipiv(:)
! .. Intrinsic Procedures ..
Intrinsic :: epsilon
! .. Executable Statements ..
Write (nout, *) 'ZGECON Example Program Results'
! Skip heading in data file
Read (nin, *)
Read (nin, *) n
lda = n
Allocate (a(lda,n), work(2*n), rwork(2*n), ipiv(n))
! Read A from data file
Read (nin, *)(a(i,1:n), i=1, n)
! Compute norm of A
anorm = zlange(norm, n, n, a, lda, rwork)
! Factorize A
Call zgetrf(n, n, a, lda, ipiv, info)
Write (nout, *)
If (info==0) Then
! Estimate condition number
Call zgecon(norm, n, a, lda, anorm, rcond, work, rwork, info)
If (rcond>=epsilon(1.0E0_dp)) Then
Write (nout, 100) 'Estimate of condition number =', 1.0_dp/rcond
Else
Write (nout, *) 'A is singular to working precision'
End If
Else
Write (nout, *) 'The factor U is singular'
End If
100 Format (1X, A, 1P, E10.2)
End Program