概要
本サンプルはFortran言語によりLAPACKルーチンZGBCONを利用するサンプルプログラムです。
入力データ
（本ルーチンの詳細はZGBCON のマニュアルページを参照）| このデータをダウンロード |
ZGBCON Example Program Data
4 1 2 :Values of N, KL and KU
(-1.65, 2.26) (-2.05,-0.85) ( 0.97,-2.84)
( 0.00, 6.30) (-1.48,-1.75) (-3.99, 4.01) ( 0.59,-0.48)
(-0.77, 2.83) (-1.06, 1.94) ( 3.33,-1.04)
( 4.48,-1.09) (-0.46,-1.72) :End of matrix A
出力結果
（本ルーチンの詳細はZGBCON のマニュアルページを参照）ソースコード
（本ルーチンの詳細はZGBCON のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program zgbcon_example
! ZGBCON Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_interfaces, Only: zgbcon, zgbtrf, zlangb
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: norm = '1'
! .. Local Scalars ..
Real (Kind=dp) :: anorm, rcond
Integer :: i, info, j, k, kl, ku, ldab, n
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: ab(:, :), work(:)
Real (Kind=dp), Allocatable :: rwork(:)
Integer, Allocatable :: ipiv(:)
! .. Intrinsic Procedures ..
Intrinsic :: epsilon, max, min
! .. Executable Statements ..
Write (nout, *) 'ZGBCON Example Program Results'
! Skip heading in data file
Read (nin, *)
Read (nin, *) n, kl, ku
ldab = 2*kl + ku + 1
Allocate (ab(ldab,n), work(2*n), rwork(n), ipiv(n))
! Read A from data file
k = kl + ku + 1
Read (nin, *)((ab(k+i-j,j),j=max(i-kl,1),min(i+ku,n)), i=1, n)
anorm = zlangb(norm, n, kl, ku, ab(kl+1,1), ldab, rwork)
! Factorize A
Call zgbtrf(n, n, kl, ku, ab, ldab, ipiv, info)
Write (nout, *)
If (info==0) Then
! Estimate condition number
Call zgbcon(norm, n, kl, ku, ab, ldab, ipiv, anorm, rcond, work, &
rwork, info)
If (rcond>=epsilon(1.0E0_dp)) Then
Write (nout, 100) 'Estimate of condition number =', 1.0E0_dp/rcond
Else
Write (nout, *) 'A is singular to working precision'
End If
Else
Write (nout, *) 'The factor U is singular'
End If
100 Format (1X, A, 1P, E10.2)
End Program