実線形方程式: 対称行列 : (右辺はベクトル)

LAPACKサンプルソースコード : 使用ルーチン名：DSYSV

ホーム > LAPACKサンプルプログラム目次 > 実線形方程式 > 対称行列

概要

本サンプルはFortran言語によりLAPACKルーチンDSYSVを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A x = b, \end{displaymath}

$ A$は対称行列です。

\begin{displaymath} A = \left( \begin{array}{rrrr} -1.81 & 2.06 & 0.63 & -1.1... ...}{r} 0.96 \\ 6.07 \\ 8.38 \\ 9.50 \end{array} \right). \end{displaymath}

$ A$の分解についての詳細 も合わせて出力されます。

入力データ

（本ルーチンの詳細はDSYSV のマニュアルページを参照）
このデータをダウンロード 
DSYSV Example Program Data
  4                         :Value of N
 -1.81   2.06   0.63  -1.15
         1.15   1.87   4.20
               -0.21   3.87
                       2.07 :End of matrix A
  0.96   6.07   8.38   9.50 :End of vector b

出力結果

（本ルーチンの詳細はDSYSV のマニュアルページを参照）
この出力例をダウンロード 
 DSYSV Example Program Results

 Solution
       -5.0000    -2.0000     1.0000     4.0000

 Details of the factorization
             1          2          3          4
 1      0.4074     0.3031    -0.5960     0.6537
 2                -2.5907     0.8115     0.2230
 3                            1.1500     4.2000
 4                                       2.0700

 Pivot indices
           1          2         -2         -2

ソースコード

（本ルーチンの詳細はDSYSV のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program dsysv_example

!     DSYSV Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
      Use lapack_interfaces, Only: dsysv
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, lda, lwork, n
!     .. Local Arrays ..
      Real (Kind=dp), Allocatable :: a(:, :), b(:), work(:)
      Integer, Allocatable :: ipiv(:)
!     .. Executable Statements ..
      Write (nout, *) 'DSYSV Example Program Results'
      Write (nout, *)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n
      lda = n
      lwork = nb*n
      Allocate (a(lda,n), b(n), work(lwork), ipiv(n))

!     Read the upper triangular part of the matrix A from data file

      Read (nin, *)(a(i,i:n), i=1, n)

!     Read b from data file

      Read (nin, *) b(1:n)

!     Solve the equations Ax = b for x
      Call dsysv('Upper', n, 1, a, lda, ipiv, b, n, work, lwork, info)

      If (info==0) Then

!       Print solution

        Write (nout, *) 'Solution'
        Write (nout, 100) b(1:n)

!       Print details of factorization

        Write (nout, *)
        Flush (nout)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_real_gen('Upper', 'Non-unit diagonal', n, &
          n, a, lda, 'Details of the factorization', ifail)

!       Print pivot indices

        Write (nout, *)
        Write (nout, *) 'Pivot indices'
        Write (nout, 110) ipiv(1:n)

      Else
        Write (nout, 120) 'The diagonal block ', info, ' of D is zero'
      End If

100   Format ((3X,7F11.4))
110   Format (1X, 7I11)
120   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks