実線形方程式: 対称正定値三重対角行列 : (右辺は行列)

LAPACKサンプルソースコード : 使用ルーチン名：DPTSVX

ホーム > LAPACKサンプルプログラム目次 > 実線形方程式 > 対称正定値三重対角行列

概要

本サンプルはFortran言語によりLAPACKルーチンDPTSVXを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A X = B, \end{displaymath}

$ A$は対称正定値三重対角行列です。

\begin{displaymath} A = \left( \begin{array}{rrrrr} 4.0 & -2.0 & 0 & 0 & 0 \\... ...0 & 9.0 \\ 14.0 & 65.0 \\ 7.0 & 23.0 \end{array} \right). \end{displaymath}

解のエラー推定値、$ A$の条件数の逆数の推定値も合わせて出力されます。

入力データ

（本ルーチンの詳細はDPTSVX のマニュアルページを参照）
このデータをダウンロード 
DPTSVX Example Program Data
  5     2                     :Values of N and NRHS
  4.0  10.0  29.0  25.0   5.0 :End of diagonal D
 -2.0  -6.0  15.0   8.0       :End of sub-diagonal E
  6.0  10.0
  9.0   4.0
  2.0   9.0
 14.0  65.0
  7.0  23.0                   :End of matrix B

出力結果

（本ルーチンの詳細はDPTSVX のマニュアルページを参照）
この出力例をダウンロード 
 DPTSVX Example Program Results

 Solution(s)
             1          2
 1      2.5000     2.0000
 2      2.0000    -1.0000
 3      1.0000    -3.0000
 4     -1.0000     6.0000
 5      3.0000    -5.0000

 Backward errors (machine-dependent)
     0.0E+00    7.4E-17

 Estimated forward error bounds (machine-dependent)
     2.4E-14    4.7E-14

 Estimate of reciprocal condition number
     9.5E-03

ソースコード

（本ルーチンの詳細はDPTSVX のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program dptsvx_example

!     DPTSVX Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
      Use lapack_interfaces, Only: dptsvx
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=dp) :: rcond
      Integer :: i, ifail, info, ldb, ldx, n, nrhs
!     .. Local Arrays ..
      Real (Kind=dp), Allocatable :: b(:, :), berr(:), d(:), df(:), e(:), &
        ef(:), ferr(:), work(:), x(:, :)
!     .. Executable Statements ..
      Write (nout, *) 'DPTSVX Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, nrhs
      ldb = n
      ldx = n
      Allocate (b(ldb,nrhs), berr(nrhs), d(n), df(n), e(n-1), ef(n-1), &
        ferr(nrhs), work(2*n), x(ldx,nrhs))

!     Read the lower bidiagonal part of the tridiagonal matrix A and
!     the right hand side b from data file

      Read (nin, *) d(1:n)
      Read (nin, *) e(1:n-1)
      Read (nin, *)(b(i,1:nrhs), i=1, n)

!     Solve the equations AX = B for X

      Call dptsvx('Not factored', n, nrhs, d, e, df, ef, b, ldb, x, ldx, &
        rcond, ferr, berr, work, info)

      If ((info==0) .Or. (info==n+1)) Then

!       Print solution, error bounds and condition number

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_real_gen('General', ' ', n, nrhs, x, ldx, &
          'Solution(s)', ifail)

        Write (nout, *)
        Write (nout, *) 'Backward errors (machine-dependent)'
        Write (nout, 100) berr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
        Write (nout, 100) ferr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimate of reciprocal condition number'
        Write (nout, 100) rcond

        If (info==n+1) Then
          Write (nout, *)
          Write (nout, *) 'The matrix A is singular to working precision'
        End If
      Else
        Write (nout, 110) 'The leading minor of order ', info, &
          ' is not positive definite'
      End If

100   Format (1X, 1P, 7E11.1)
110   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks