概要
本サンプルはFortran言語によりLAPACKルーチンDPOSVXを利用するサンプルプログラムです。
以下の式を解きます。
は対称正定値行列です。
解のエラー推定値、均衡化についての情報、スケーリングされた行列
の条件数の逆数の推定値も合わせて出力されます。
入力データ
（本ルーチンの詳細はDPOSVX のマニュアルページを参照）| このデータをダウンロード |
DPOSVX Example Program Data
4 2 :Values of N and NRHS
4.16 -3.12 0.56 -0.10
5.03 -0.83 1.18
0.76 0.34
1.18 :End of matrix A
8.70 8.30
-13.35 2.13
1.89 1.61
-4.14 5.00 :End of matrix B
出力結果
（本ルーチンの詳細はDPOSVX のマニュアルページを参照）| この出力例をダウンロード |
DPOSVX Example Program Results
Solution(s)
1 2
1 1.0000 4.0000
2 -1.0000 3.0000
3 2.0000 2.0000
4 -3.0000 1.0000
Backward errors (machine-dependent)
6.7E-17 7.9E-17
Estimated forward error bounds (machine-dependent)
2.3E-14 2.3E-14
Estimate of reciprocal condition number
1.0E-02
A has not been equilibrated
ソースコード
（本ルーチンの詳細はDPOSVX のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program dposvx_example
! DPOSVX Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
Use lapack_interfaces, Only: dposvx
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
! .. Local Scalars ..
Real (Kind=dp) :: rcond
Integer :: i, ifail, info, lda, ldaf, ldb, ldx, n, nrhs
Character (1) :: equed
! .. Local Arrays ..
Real (Kind=dp), Allocatable :: a(:, :), af(:, :), b(:, :), berr(:), &
ferr(:), s(:), work(:), x(:, :)
Integer, Allocatable :: iwork(:)
! .. Executable Statements ..
Write (nout, *) 'DPOSVX Example Program Results'
Write (nout, *)
Flush (nout)
! Skip heading in data file
Read (nin, *)
Read (nin, *) n, nrhs
lda = n
ldaf = n
ldb = n
ldx = n
Allocate (a(lda,n), af(ldaf,n), b(ldb,nrhs), berr(nrhs), ferr(nrhs), &
s(n), work(3*n), x(ldx,nrhs), iwork(n))
! Read the upper triangular part of A from data file
Read (nin, *)(a(i,i:n), i=1, n)
! Read B from data file
Read (nin, *)(b(i,1:nrhs), i=1, n)
! Solve the equations AX = B for X
Call dposvx('Equilibration', 'Upper', n, nrhs, a, lda, af, ldaf, equed, &
s, b, ldb, x, ldx, rcond, ferr, berr, work, iwork, info)
If ((info==0) .Or. (info==n+1)) Then
! Print solution, error bounds, condition number and the form
! of equilibration
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_real_gen('General', ' ', n, nrhs, x, ldx, &
'Solution(s)', ifail)
Write (nout, *)
Write (nout, *) 'Backward errors (machine-dependent)'
Write (nout, 100) berr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
Write (nout, 100) ferr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimate of reciprocal condition number'
Write (nout, 100) rcond
Write (nout, *)
If (equed=='N') Then
Write (nout, *) 'A has not been equilibrated'
Else If (equed=='Y') Then
Write (nout, *) &
'A has been row and column scaled as diag(S)*A*diag(S)'
End If
If (info==n+1) Then
Write (nout, *)
Write (nout, *) 'The matrix A is singular to working precision'
End If
Else
Write (nout, 110) 'The leading minor of order ', info, &
' is not positive definite'
End If
100 Format ((3X,1P,7E11.1))
110 Format (1X, A, I3, A)
End Program