概要
本サンプルはFortran言語によりLAPACKルーチンDPBSVXを利用するサンプルプログラムです。
以下の式を解きます。
は対称正定値帯行列です。
解のエラー推定値、均衡化についての情報、スケーリングされた行列
の条件数の逆数の推定値も合わせて出力されます。
入力データ
（本ルーチンの詳細はDPBSVX のマニュアルページを参照）| このデータをダウンロード |
DPBSVX Example Program Data
4 1 2 :Values of N, KD and NRHS
5.49 2.68
5.63 -2.39
2.60 -2.22
5.17 :End of matrix A
22.09 5.10
9.31 30.81
-5.24 -25.82
11.83 22.90 :End of matrix B
出力結果
（本ルーチンの詳細はDPBSVX のマニュアルページを参照）| この出力例をダウンロード |
DPBSVX Example Program Results
Solution(s)
1 2
1 5.0000 -2.0000
2 -2.0000 6.0000
3 -3.0000 -1.0000
4 1.0000 4.0000
Backward errors (machine-dependent)
8.6E-17 1.1E-16
Estimated forward error bounds (machine-dependent)
2.0E-14 2.8E-14
Estimate of reciprocal condition number
1.3E-02
A has not been equilibrated
ソースコード
（本ルーチンの詳細はDPBSVX のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program dpbsvx_example
! DPBSVX Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
Use lapack_interfaces, Only: dpbsvx
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: uplo = 'U'
! .. Local Scalars ..
Real (Kind=dp) :: rcond
Integer :: i, ifail, info, j, kd, ldab, ldafb, ldb, ldx, n, nrhs
Character (1) :: equed
! .. Local Arrays ..
Real (Kind=dp), Allocatable :: ab(:, :), afb(:, :), b(:, :), berr(:), &
ferr(:), s(:), work(:), x(:, :)
Integer, Allocatable :: iwork(:)
! .. Intrinsic Procedures ..
Intrinsic :: max, min
! .. Executable Statements ..
Write (nout, *) 'DPBSVX Example Program Results'
Write (nout, *)
Flush (nout)
! Skip heading in data file
Read (nin, *)
Read (nin, *) n, kd, nrhs
ldb = n
ldx = n
ldab = kd + 1
ldafb = kd + 1
Allocate (ab(ldab,n), afb(ldafb,n), b(ldb,nrhs), berr(nrhs), ferr(nrhs), &
s(n), work(3*n), x(ldx,nrhs), iwork(n))
! Read the upper or lower triangular part of the band matrix A
! from data file
If (uplo=='U') Then
Read (nin, *)((ab(kd+1+i-j,j),j=i,min(n,i+kd)), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ab(1+i-j,j),j=max(1,i-kd),i), i=1, n)
End If
! Read B from data file
Read (nin, *)(b(i,1:nrhs), i=1, n)
! Solve the equations AX = B for X
Call dpbsvx('Equilibration', uplo, n, kd, nrhs, ab, ldab, afb, ldafb, &
equed, s, b, ldb, x, ldx, rcond, ferr, berr, work, iwork, info)
If ((info==0) .Or. (info==n+1)) Then
! Print solution, error bounds, condition number and the form
! of equilibration
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_real_gen('General', ' ', n, nrhs, x, ldx, &
'Solution(s)', ifail)
Write (nout, *)
Write (nout, *) 'Backward errors (machine-dependent)'
Write (nout, 100) berr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
Write (nout, 100) ferr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimate of reciprocal condition number'
Write (nout, 100) rcond
Write (nout, *)
If (equed=='N') Then
Write (nout, *) 'A has not been equilibrated'
Else If (equed=='Y') Then
Write (nout, *) &
'A has been row and column scaled as diag(S)*A*diag(S)'
End If
If (info==n+1) Then
Write (nout, *)
Write (nout, *) 'The matrix A is singular to working precision'
End If
Else
Write (nout, 110) 'The leading minor of order ', info, &
' is not positive definite'
End If
100 Format ((3X,1P,7E11.1))
110 Format (1X, A, I3, A)
End Program